您的地位:网站首页>Ansys教程>

ANSYS弹簧质点模子的地动阐发

光阴>2019-05-20 来源:网络

注:此命令流是一个很好的地动阐发示例,包含模态阐发、反应谱阐发和时程能源阐发。

! 一个四层弹簧-质点模子的地动ANSYS阐发
! Example of seismic analysis in ANSYS
! 包含频率阐发,谱阐发和时程阐发
! With model & frequency analysis, spectrum analysis and transient analysis
! 作者:陆新征,清华大学土木匠程系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University

FINI
/CLEAR
/UNITS,SI
/PREP7
DAMPRATIO=0.02 !振型阻尼系数都为0.02
ET,1,BEAM188
KEYOPT,1,7,1
KEYOPT,1,8,1
ET,2,MASS21,,,4
MP,EX,1,210E9
MP,NUXY,1,0.3
MP,DENS,1,7800
MPDATA,DAMP,1,,DAMPRATIO
SECTYPE,3,BEAM,I
SECDATA,0.2,0.2,0.5,0.01,0.01,0.008
R,1,1.6E2,1.6E2
R,2,1.2E2,1.2E2
K,1,0,0,0
K,2,0,3,0
K,3,0,6,0
K,4,0,9,0
K,5,0,12,0
K,6,0,0,10000
L,1,2
L,2,3
L,3,4
L,4,5
LSEL,,,,1,4
LATT,1,0,1,,6,,3
ALLS
LESIZE,ALL, , ,3 , , , , ,1
LMESH,ALL
NUMMRG,ALL
NUMCMP,ALL
TYPE,2
REAL,1
E,2
TYPE,2
REAL,2
E,8
E,14
E,20
*SET,NT,1001
*SET,DT,0.02
*DIM,AC,,NT
*VREAD,AC(1),RECORD,TXT
(F8.3)
/SOLU
D,1,ALL,
ANTYPE,0
SOLVE
FINISH
/SOLU !模态阐发
ANTYPE,2
MODOPT,SUBSP,8
MXPAND,8, , ,1
SOLVE
FINI
!获得自振频率1
*GET,FREQ1,MODE,1,FREQ
/ESHAPE,1.0
/SOLU
ANTYPE,SPECTR !谱阐发
SPOPT,SPRS
MDAMP,1,DAMPRATIO, , , , , ,
SED,1
SVTYPE,2,1
FREQ,0.167,0.25,0.333,0.44444,0.5,0.667,1,1.25,1.667
SV,,0.154350625,0.191590625,0.210210625,0.224175625,0.250716714,0.329514922,0.484352764,0.598723486,0.786897371
FREQ,2.222,10,100000
SV,,1.034212766,1.034212766,0.3528
!按7度多遇地动,地动影响系数0.08 第一组III场地TG=0.45
SRSS,0.01,DISP
SOLVE
FINISH
/POST1
/INP,,MCOM
NSORT,U,SUM
*GET,DMAX_SPE,SORT, ,MAX !反应谱最大变形

!开端地动计算
FINISH
/CONFIG,NRES,20000
/SOLU
ANTYPE,TRANS
TRNOPT,FULL
!设定瑞雷阻尼数值
ALPHAD,2*DAMPRATIO*FREQ1*2*3.1415926
BETAD,2*DAMPRATIO/(FREQ1*2*3.1415926)

*DO,I,1,1001
ACEL,AC(I),0,0
TIME,I*0.02
OUTRES,ALL,ALL
SOLVE
*ENDDO
FINISH

/POST26
FILE
NSOL,2,20,U,X,
PLVAR,2, , , , , , , , , ,
STORE,MERGE
XVAR,1
PLVAR,2,
*GET,DMAX_TRANS,VARI,2,EXTREM,VMAX, , ! 时程阐发最大位移

命令流及地动记载文件下载:

ansysExam_Quake.rar



友情链接:中国物资网  最新网络新闻网  武汉工商门户网  商业评论网  中国太阳能光伏网  中国江苏消防网  西安市第八十二中学  南京电子资讯网  乐骁游戏网  中学历史学习网站